10 PRINT "Hurkle"
20 PRINT "PEOPLE'S COMPUTER COMPANY, MENLO PARK CA"
30 PRINT "Converted by Dick Whipple for TINY BASIC MEGA"
40 PRINT
50 PRINT
60 PRINT
100 LET X=RND(1)
110 LET N=5
120 LET G=10
125 IF G < 20 THEN 210
130 PRINT "G must not exceed 20"
135 END
210 PRINT 
220 PRINT "A hurkle is hiding on a";G;"by";G;"grid. Homebase"
230 PRINT "on the grid is 0,0. Guess is a pair of numbers."
240 PRINT "Press ENTER after each number. Try to"
250 PRINT "guess the hurkle's gridpoint. You get";N;"tries."
260 PRINT "After each try, I will tell you the approximate"
270 PRINT "direction to go to look for the hurkle."
280 PRINT 
285 LET A=G/10*RND(1)/1000+1
286 LET B=G/10*RND(1)/1000+1
310 LET K=1
320 PRINT "Guess #";K;
330 INPUT X,Y
340 IF X-A <> 0 THEN 360
345 IF Y-B <> 0 THEN 360
350 GOTO 510
360 GOSUB 610 
370 PRINT 
380 LET K=K+1
385 IF K<=N THEN 320
410 PRINT 
420 PRINT "Sorry, that's";N;"guesses."
430 PRINT "The hurkle is at ";A;",";B
440 PRINT 
450 PRINT "Let's play again. Hurkle is hiding."
460 PRINT 
470 GOTO 285 
510 PRINT 
520 PRINT "You found him in";K;"guesses!"
540 GOTO 440 
610 PRINT "Go ";
620 IF Y=B  THEN 670 
630 IF Y<B  THEN 660
640 PRINT "south";
650 GOTO 670 
660 PRINT "north";
670 IF X=A  THEN 720 
680 IF X<A  THEN 710
690 PRINT "west";
700 GOTO 720 
710 PRINT "east";
720 PRINT 
730 RETURN
999 END